google-cloud-kms-3.12.0nest

download

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1 edo pypi

DESCRIPTION="Python Client for Google Cloud Key Management Service"
HOMEPAGE="https://github.com/googleapis/google-cloud-python"

LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64"

RDEPEND="dev-python/google-api-core[${PYTHON_USEDEP}]
	dev-python/google-auth[${PYTHON_USEDEP}]
	dev-python/grpcio[${PYTHON_USEDEP}]
	dev-python/grpc-google-iam-v1[${PYTHON_USEDEP}]
	dev-python/protobuf[${PYTHON_USEDEP}]
	dev-python/proto-plus[${PYTHON_USEDEP}]"

EPYTEST_PLUGINS=( pytest-asyncio )
distutils_enable_tests pytest

EPYTEST_DESELECT=(
	# need valid PROJECT_ID (KeyError: 'PROJECT_ID')
	tests/system/smoke_test.py::test_list_ekm_connections
)

python_compile() {
	distutils-r1_python_compile
	edo find "${BUILD_DIR}" -name '*.pth' -delete
}

src_test() {
	edo rm -r google
	distutils-r1_src_test
}

python_test() {
	distutils_write_namespace google
	epytest -v tests
}