carnage-1.5guru

download

# Copyright 2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=flit
PYTHON_COMPAT=( python3_{12..14} )

inherit distutils-r1 optfeature desktop xdg

DESCRIPTION="TUI front-end for Portage and eix"
HOMEPAGE="https://github.com/dsafxP/carnage"

if [[ ${PV} == *9999 ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/dsafxP/carnage.git"
else
	SRC_URI="https://github.com/dsafxP/carnage/archive/v${PV}.tar.gz -> ${P}.tar.gz"
	KEYWORDS="~amd64"
fi

LICENSE="MIT"
SLOT="0"

RDEPEND="
	>=app-eselect/eselect-repository-14
	>=app-portage/gentoolkit-0.7.1[${PYTHON_USEDEP}]
	>=dev-python/lxml-6.0.2[${PYTHON_USEDEP}]
	>=dev-python/msgpack-1.1.2[${PYTHON_USEDEP}]
	>=dev-python/platformdirs-4.9.6[${PYTHON_USEDEP}]
	>=dev-python/textual-8.0.0[${PYTHON_USEDEP}]
	>=dev-python/tomlkit-0.14.0[${PYTHON_USEDEP}]
	>=sys-apps/portage-3.0.77[${PYTHON_USEDEP}]
"

src_install() {
	distutils-r1_src_install

	domenu assets/carnage.desktop

	doicon -s scalable assets/carnage.svg

	doman man/carnage.1
}

pkg_postinst() {
	optfeature "package & use flag browsing" app-portage/eix
	optfeature "desktop notifications" dev-python/desktop-notifier
}