rubocop-rspec_rails-2.32.0graaff

download

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8
USE_RUBY="ruby32 ruby33 ruby34"

RUBY_FAKEGEM_EXTRADOC="CHANGELOG.md README.md"

RUBY_FAKEGEM_RECIPE_TEST="rspec3"

RUBY_FAKEGEM_EXTRAINSTALL="config"

RUBY_FAKEGEM_BINWRAP=""

RUBY_FAKEGEM_GEMSPEC="rubocop-rspec_rails.gemspec"

inherit ruby-fakegem

DESCRIPTION="Code style checking for RSpec files"
HOMEPAGE="https://github.com/rubocop/rubocop-rspec_rails"
SRC_URI="https://github.com/rubocop/rubocop-rspec_rails/archive/v${PV}.tar.gz -> ${P}.tar.gz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="test"

ruby_add_rdepend "
	>=dev-ruby/lint_roller-1.1:1
	=dev-ruby/rubocop-1* >=dev-ruby/rubocop-1.72.1
	>=dev-ruby/rubocop-rspec-3.5:3
"

ruby_add_depend "test? ( dev-ruby/bundler dev-ruby/yard )"

all_ruby_prepare() {
	sed -e '/simplecov/ s:^:#:' \
		-i spec/spec_helper.rb || die

	sed -e '/\(bump\|performance\|rake\|simplecov\)/ s:^:#:' \
		-i Gemfile || die
	rm -f tasks/cut_release.rake || die
	sed -e 's/documentation/progress/' \
		-i .rspec || die
}

each_ruby_test() {
	${RUBY} -S rake spec || die
}