dbus-cpp-5.0.6gentoo-lomiri

download

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit lomiri

if [[ ${PV} == 9999 ]]; then
    KEYWORDS=""
    EGIT_REPO_URI="https://gitlab.com/ubports/development/core/lib-cpp/${PN}.git"
    inherit git-r3
else
    KEYWORDS="~amd64"
    SRC_URI="https://gitlab.com/ubports/development/core/lib-cpp/${PN}/-/archive/${PV}/${P}.tar.gz"
fi

DESCRIPTION="A header-only dbus-binding leveraging C++-11"
HOMEPAGE="https://gitlab.com/ubports/development/core/lib-cpp/${PN}"
LICENSE="GPL-3"
SLOT="0"
RESTRICT="test mirror"

DEPEND="
    dev-cpp/process-cpp
    dev-libs/boost
    dev-libs/libxml2
    sys-apps/dbus
"
RDEPEND="${DEPEND}"

BDEPEND="
    dev-build/cmake
    dev-build/cmake-extras
    dev-build/samurai
"

src_prepare() {
    # remove tests
    cmake_comment_add_subdirectory tests

    # remove examples
    cmake_comment_add_subdirectory examples

    # remove coverage report
    sed -i '/include(cmake\/EnableCoverageReport.cmake)/d' CMakeLists.txt || die
    sed -i '/enable_coverage_report(benchmark)/d' CMakeLists.txt || die

    # remove 'prepush' functionality -> complains about missing 'android-build'
    sed -i '/include(cmake\/PrePush.cmake)/d' CMakeLists.txt || die

    lomiri_src_prepare
}