openbox-3.7_rc2flussence

download

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit autotools

DESCRIPTION="Standards compliant, fast, light-weight, extensible window manager"
HOMEPAGE="http://openbox.org/wiki/Main_Page"
SRC_URI="https://github.com/Mikachu/${PN}/archive/refs/tags/release-${PV/_/-}.tar.gz"
S="${WORKDIR}/${PN}-release-${PV/_/-}"
LICENSE="GPL-2"
SLOT="3"
KEYWORDS="~amd64 ~x86"
IUSE="debug imlib nls session startup-notification svg"

BDEPEND="
	sys-devel/gettext
	virtual/pkgconfig
"
RDEPEND="
	dev-libs/glib:2
	>=dev-libs/libxml2-2.0:=
	>=media-libs/fontconfig-2
	x11-libs/cairo
	x11-libs/libXau
	x11-libs/libXcursor
	x11-libs/libXext
	x11-libs/libXft
	x11-libs/libXinerama
	x11-libs/libXrandr
	x11-libs/libXt
	>=x11-libs/pango-1.8[X]
	imlib? ( media-libs/imlib2 )
	startup-notification? ( >=x11-libs/startup-notification-0.8 )
	svg? ( gnome-base/librsvg:2 )
"
DEPEND="${RDEPEND}
	x11-base/xorg-proto
"

src_prepare() {
	eautoreconf
	default
}

src_configure() {
	local myeconfargs=(
		--disable-static
		--with-x
		"$(use_enable debug)"
		"$(use_enable imlib imlib2)"
		"$(use_enable nls)"
		"$(use_enable session session-management)"
		"$(use_enable startup-notification)"
		"$(use_enable svg librsvg)"
	)
	econf "${myeconfargs[@]}"
}

src_install() {
	exeinto /etc/X11/Sessions
	newexe - "${PN}" <<-EOF
	#!/bin/sh
	openbox-session
	EOF

	emake DESTDIR="${D}" install
	find "${ED}" -name '*.la' -delete || die
	rm "${ED}"/usr/libexec/openbox-xdg-autostart || die
}