rtags-9999flow

download

# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit cmake systemd

if [[ "${PV}" == "9999" ]]; then
	inherit git-r3
	EGIT_REPO_URI="https://github.com/Andersbakken/rtags.git"
else
	RCT_COMMIT_ID="f926ecb00d39bfd163ff4084013a3f546558695a"
	RCT_TAR_GZ="rct-${RCT_COMMIT_ID}.tar.gz"
	SRC_URI="
		https://github.com/Andersbakken/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
		https://github.com/Andersbakken/rct/archive/${RCT_COMMIT_ID}.tar.gz -> ${RCT_TAR_GZ}
	"
	KEYWORDS="~amd64"
fi

DESCRIPTION="A client/server indexer for C/C++/ObjC[++] with integration for Emacs"
HOMEPAGE="http://www.rtags.net/"

# rtags is GPL-3 licensed, but the rct library (from the same author
# as rtags) is BSD-4 licensed.
LICENSE="GPL-3 BSD-4"
SLOT="0"

# TODO:
# - dev-libs/openssl is an automagic dep of rct
# - sys-libs/zlib is an automagic dep of rct
# - is sys-libs/ncurses still required by rtags/rct?
DEPEND="
	dev-libs/openssl:0=
	llvm-core/clang:*
	sys-libs/ncurses:0
	virtual/zlib
"
RDEPEND="${DEPEND}"

src_unpack() {
	default

	[[ "${PV}" == "9999" ]] && return

	rmdir "${S}/src/rct" || die
	ln -rs "${WORKDIR}"/rct-* "${S}/src/rct" || die
}

src_install() {
	cmake_src_install

	systemd_douserunit \
		"${FILESDIR}/rdm.socket" \
		"${FILESDIR}/rdm.service"
}