kdepim-runtime-26.04.3gentoo

download

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

PATCHSET="kdepim-26.04.3-ki18n-6.28-findpkg"
ECM_TEST="forceoptional"
PVCUT=$(ver_cut 1-3)
KFMIN=6.22.0
QTMIN=6.10.1
inherit ecm gear.kde.org xdg

DESCRIPTION="Runtime plugin collection to extend the functionality of KDE PIM"
HOMEPAGE="https://apps.kde.org/kontact/"
SRC_URI+=" https://dev.gentoo.org/~asturm/distfiles/kde/${PATCHSET}.tar.xz"

LICENSE="GPL-2+ LGPL-2.1+"
SLOT="6/$(ver_cut 1-2)"
KEYWORDS="amd64 arm64"
IUSE="activities +ews speech"

RESTRICT="test"

RDEPEND="
	dev-libs/cyrus-sasl:2
	>=dev-libs/qtkeychain-0.16.0:=
	>=dev-libs/ktextaddons-2.0.1:6
	>=dev-qt/qtbase-${QTMIN}:6[concurrent,dbus,gui,network,widgets,xml]
	>=dev-qt/qtnetworkauth-${QTMIN}:6
	>=kde-apps/akonadi-${PVCUT}:6=
	>=kde-apps/akonadi-calendar-${PVCUT}:6=
	>=kde-apps/akonadi-contacts-${PVCUT}:6=
	>=kde-apps/akonadi-mime-${PVCUT}:6=
	>=kde-apps/kcalutils-${PVCUT}:6=
	>=kde-apps/kidentitymanagement-${PVCUT}:6=
	>=kde-apps/kimap-${PVCUT}:6=
	>=kde-apps/kldap-${PVCUT}:6=
	>=kde-apps/kmailtransport-${PVCUT}:6=
	>=kde-apps/kmbox-${PVCUT}:6=
	>=kde-apps/kmime-${PVCUT}:6=
	>=kde-apps/libkgapi-${PVCUT}:6=
	>=kde-apps/pimcommon-${PVCUT}:6=[activities?]
	>=kde-frameworks/kcalendarcore-${KFMIN}:6
	>=kde-frameworks/kcmutils-${KFMIN}:6
	>=kde-frameworks/kcodecs-${KFMIN}:6
	>=kde-frameworks/kcompletion-${KFMIN}:6
	>=kde-frameworks/kconfig-${KFMIN}:6
	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
	>=kde-frameworks/kcontacts-${KFMIN}:6
	>=kde-frameworks/kcoreaddons-${KFMIN}:6
	>=kde-frameworks/kdav-${KFMIN}:6
	>=kde-frameworks/ki18n-${KFMIN}:6
	>=kde-frameworks/kio-${KFMIN}:6
	>=kde-frameworks/kitemmodels-${KFMIN}:6
	>=kde-frameworks/kjobwidgets-${KFMIN}:6
	>=kde-frameworks/knotifications-${KFMIN}:6
	>=kde-frameworks/knotifyconfig-${KFMIN}:6
	>=kde-frameworks/kservice-${KFMIN}:6
	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
	>=kde-frameworks/kwindowsystem-${KFMIN}:6
	>=kde-frameworks/kxmlgui-${KFMIN}:6
	activities? ( kde-plasma/plasma-activities:6= )
	ews? (
		>=app-crypt/qca-2.3.7:2[qt6(+)]
		>=dev-qt/qtwebengine-${QTMIN}:6[widgets]
	)
	speech? ( >=dev-qt/qtspeech-${QTMIN}:6 )
"
DEPEND="${RDEPEND}
	test? (
		>=kde-apps/akonadi-${PVCUT}:6[tools]
		>=kde-apps/kimap-${PVCUT}:6[test]
	)
"

PATCHES=(
	"${FILESDIR}/${PN}-26.04.2-ews-optional.patch" # in 26.12
	"${WORKDIR}/${PATCHSET}/${PN}.patch" # bug #979240
)

src_prepare() {
	ecm_src_prepare
	# never provided by Gentoo, dropped upstream in git master
	cmake_comment_add_subdirectory -f resources kolab
}

src_configure() {
	local mycmakeargs=(
		-DOPTION_USE_PLASMA_ACTIVITIES=$(usex activities)
		-DKDEPIM_EWS=$(usex ews)
		$(cmake_use_find_package speech Qt6TextToSpeech)
		-DKDEPIM_RUN_AKONADI_TEST=$(usex test)
		-DCMAKE_DISABLE_FIND_PACKAGE_Etebase=ON
	)
	ecm_src_configure
}