pydantic-2.13.4gentoo

download

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_EXT=1
DISTUTILS_USE_PEP517=hatchling
# no provenance for pydantic-core:
# https://github.com/pydantic/pydantic-core/issues/1842
PYPI_VERIFY_REPO=https://github.com/pydantic/pydantic
PYTHON_COMPAT=( python3_{12..15} )

PYDANTIC_CORE_PV=2.46.${PV##*.}
RUST_MIN_VER="1.88.0"
CRATES="
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]+wasi-0.2.4
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
	[email protected]
"

inherit cargo distutils-r1 pypi

DESCRIPTION="Data parsing and validation using Python type hints"
HOMEPAGE="
	https://github.com/pydantic/pydantic/
	https://pypi.org/project/pydantic/
"
# pydantic-core & pydantic have a perfect circular test dep now
SRC_URI+="
	$(pypi_sdist_url pydantic_core "${PYDANTIC_CORE_PV}")
	${CARGO_CRATE_URIS}
"
PYDANTIC_CORE_S=${WORKDIR}/pydantic_core-${PYDANTIC_CORE_PV}

LICENSE="MIT"
# Dependent crate licenses
LICENSE+="
	Apache-2.0-with-LLVM-exceptions MIT Unicode-3.0 Unicode-DFS-2016
	ZLIB
"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"

RDEPEND="
	>=dev-python/annotated-types-0.6.0[${PYTHON_USEDEP}]
	>=dev-python/typing-extensions-4.14.1[${PYTHON_USEDEP}]
	>=dev-python/typing-inspection-0.4.2[${PYTHON_USEDEP}]
	dev-python/tzdata[${PYTHON_USEDEP}]
	!dev-python/pydantic-core
"
BDEPEND="
	>=dev-python/hatch-fancy-pypi-readme-22.5.0[${PYTHON_USEDEP}]
	dev-util/maturin[${PYTHON_USEDEP}]
	test? (
		dev-python/cloudpickle[${PYTHON_USEDEP}]
		dev-python/dirty-equals[${PYTHON_USEDEP}]
		>=dev-python/email-validator-2.0.0[${PYTHON_USEDEP}]
		>=dev-python/faker-18.13.0[${PYTHON_USEDEP}]
		>=dev-python/jsonschema-4.23.0[${PYTHON_USEDEP}]
		dev-python/pytz[${PYTHON_USEDEP}]
		dev-python/rich[${PYTHON_USEDEP}]
	)
"
# pydantic-core
BDEPEND+="
	test? (
		>=dev-python/dirty-equals-0.5.0[${PYTHON_USEDEP}]
		>=dev-python/inline-snapshot-0.13.3[${PYTHON_USEDEP}]
		>=dev-python/typing-inspection-0.4.1[${PYTHON_USEDEP}]
	)
"

EPYTEST_PLUGINS=( hypothesis pytest-mock )
distutils_enable_tests pytest

QA_FLAGS_IGNORED="usr/lib.*/py.*/site-packages/pydantic_core/_pydantic_core.*.so"

src_unpack() {
	pypi_src_unpack
	cargo_src_unpack
}

src_prepare() {
	sed -i -e '/benchmark/d' {.,"${PYDANTIC_CORE_S}"}/pyproject.toml || die
	sed -i -e '/^strip/d' "${PYDANTIC_CORE_S}"/Cargo.toml || die
	distutils-r1_src_prepare
}

python_compile() {
	distutils-r1_python_compile

	local DISTUTILS_USE_PEP517=maturin
	local DISTUTILS_UPSTREAM_PEP517=maturin
	cd "${PYDANTIC_CORE_S}" || die
	distutils-r1_python_compile
	cd - >/dev/null || die
}

python_test() {
	local EPYTEST_DESELECT=(
		# == pydantic ==
		# -Werror, sigh
		tests/test_types_typeddict.py::test_readonly_qualifier_warning
		# random regressions?
		tests/test_deprecated_fields.py::test_computed_field_deprecated
		tests/test_deprecated_fields.py::test_deprecated_field_forward_annotation
		tests/test_deprecated_fields.py::test_deprecated_fields
		tests/test_deprecated_fields.py::test_deprecated_fields_deprecated_class
		tests/test_deprecated_fields.py::test_deprecated_with_boolean

		# == pydantic-core ==
		# TODO: recursion till segfault
		tests/serializers/test_functions.py::test_recursive_call
	)
	local EPYTEST_IGNORE=(
		# require pytest-examples (pydantic)
		tests/test_docs.py
		# benchmarks (both)
		tests/benchmarks
	)

	if ! has_version "dev-python/cloudpickle[${PYTHON_USEDEP}]"; then
		EPYTEST_IGNORE+=(
			# (pydantic)
			tests/test_pickle.py
		)
	fi

	case ${EPYTHON} in
		python3.15*)
			EPYTEST_DESELECT+=(
				tests/test_types.py::test_base64url_invalid
			)
			;;
	esac

	cd "${PYDANTIC_CORE_S}" || die
	rm -rf pydantic_core || die
	cargo_src_test
	epytest -o xfail_strict=False -o addopts=
	cd - 2>/dev/null || die

	epytest
}