distributed-2026.7.1stuff

download

# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{12..14} )
# GitHub tarballs have no git metadata; keep setuptools-scm happy.
export SETUPTOOLS_SCM_PRETEND_VERSION_FOR_DISTRIBUTED=${PV}

inherit distutils-r1

DESCRIPTION="Distributed scheduler for Dask"
HOMEPAGE="
	https://distributed.dask.org/
	https://github.com/dask/distributed/
	https://pypi.org/project/distributed/
"
SRC_URI="
	https://github.com/dask/distributed/archive/${PV}.tar.gz -> ${P}.gh.tar.gz
"

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
RESTRICT="test"	# Upstream test suite is flaky / network-dependent.

# Upstream also excludes tblib 3.2.0/3.2.1 (broken releases); neither is in
# ::gentoo (only 3.2.2), so the != atoms are moot and omitted. verified 2026-07-14
RDEPEND="
	>=dev-python/click-8.0[${PYTHON_USEDEP}]
	>=dev-python/cloudpickle-3.0.0[${PYTHON_USEDEP}]
	>=dev-python/dask-${PV}[${PYTHON_USEDEP}]
	<dev-python/dask-2026.7.2[${PYTHON_USEDEP}]
	>=dev-python/jinja2-2.10.3[${PYTHON_USEDEP}]
	>=dev-python/locket-1.0.0[${PYTHON_USEDEP}]
	>=dev-python/msgpack-1.0.2[${PYTHON_USEDEP}]
	>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
	>=dev-python/psutil-5.8.0[${PYTHON_USEDEP}]
	>=dev-python/pyyaml-5.4.1[${PYTHON_USEDEP}]
	>=dev-python/sortedcontainers-2.0.5[${PYTHON_USEDEP}]
	>=dev-python/tblib-1.6.0[${PYTHON_USEDEP}]
	>=dev-python/toolz-0.12.0[${PYTHON_USEDEP}]
	>=dev-python/tornado-6.2.0[${PYTHON_USEDEP}]
	>=dev-python/zict-3.0.0[${PYTHON_USEDEP}]
"
BDEPEND="
	>=dev-python/setuptools-scm-9.0[${PYTHON_USEDEP}]
"

EPYTEST_PLUGINS=()
distutils_enable_tests pytest

python_prepare_all() {
	sed -i -e '/--cov/d' pyproject.toml || die
	distutils-r1_python_prepare_all
}